Ecuaciones Diferenciales

> restart;

Instrucciones.

dsolve

La instrucción que resuelve ecuaciones diferenciales es ( dsolve ), cuya sintaxis es:

• dsolve( ecuación);
• dsolve( {ecuación, conds_ini}, fun(var), opciones)

Peculiaridades:

• La ecuación puede ser dada en términos de diff o D, aplicados a una función u operador flecha:
• Si no hay signo "=", Maple V asume igualación a cero
• Las condiciones iniciales son una secuencia de ecuaciones de la forma

• donde son constantes simbólicas o valores numéricos

Las opciones son varios tipos (ver hoja de ayuda [ dsolve ]). Las que mas usaremos son de la forma:

• type=series --------- solución aproximada en series de potencias
• type-numeric ------------ solución numérica

• output=procedurelist --------------- despliegue en forma de lista
• value=array([x0,x1,.....xn]) ----------- despliegue como arreglo de valores

odeplot

Para graficar soluciones numéricas usamos la instrucción ( odeplot ) que pertence al paquete plots.

La sintaxis es:

donde F es un nombre asignado a la solución numérica, son valores numéricos del rango de la variable independiente, las opciones son las de plot.

paquete DEtools

Es un paquete de graficación de soluciones numéricas de ecuaciones diferenciales, campos de pendientes (isoclinas), espacios de fase, etc. Se recomienda consultar la hoja de ayuda ( DEtools )

>

Solucion simbólica.

Maple V puede resolver analiticamente una gran cantidad de ecuaciones diferenciales

> ecd1:=diff(x(t),t$2)+u*diff(x(t),t)+k*x(t)=1;

Solucion general:

> sol1:=dsolve(ecd1);

Para comprobar la solución, sustituimos y evaluamos

> eval(subs(x(t)=rhs(sol1),ecd1));

La instrucción map , simplifica en ambas miembros

> map(simplify,%);

Condiciones iniciales

> ci_1:=x(0)=1, D(x)(0)=0;

> sol1_ptc:=dsolve({ecd1,ci_1}, x(t));

Nota: es posible introducir condiciones iniciales simbólicas (intentarlo...)

Ejercicio

Graficar la solución obtenida, para los valores

Solucion aproximada

La opción type=series da la solución en series de potencias

> ecd1; ci_1;

> sol1_apr:=dsolve({ecd1,ci_1}, x(t), type=series);

Ejercicio

Comparar la solución analítica y la aproximada, para los valores , en el rango . TIP: es necesario convertir la serie en polinomio para poder graficar la serie truncada

Solucion numerica.

La opción type=numeric lleva a la solución numérica, sin embargo esta opción no acepta parámetros simbólicos (como ). Por lo tanto, asignaremos valores numéricos a estos parámetros

> ecd2:=subs(u=2, k=1, ecd1);

Las condiciones iniciales deben ser puramente numéricas

> ci_2:=x(0)=0,D(x)(0)=1;

> S:=dsolve({ecd2,ci_2}, x(t), type=numeric);

S es una función numérica

> S(0); S(0.5); S(0.7);

La gráfica de la solución numérica se obtiene con la instrucción odeplot , del paquete plots .

> plots[odeplot](S,[t,x(t)],-1..1);

Ejercicio

Trazar las gráficas de la solución exacta y la aproximada en series junto con la gráfica de la solución numérica. Asignar un color o estilo diferente a cada curva.

Una forma muy útil para examinar una solucion numérica es pedir el resultado en forma de un arreglo de n valores iniciales. Esto se logra con la opcion display=array([t1, t2......., tn]) , donde t1......tn son n valores de t.

> SS:=dsolve({ecd2,ci_2}, x(t), type=numeric,value=array([0,0.1,0.3,0.5]));

Los valores del arreglo los podemos introducir como una lista que depende de

> IN:=(t1,tn,n)->[seq(t1+i*(tn-t1)/(n-1),i=0..n-1)];

Por ejemplo, 6 valores de t en el rango

> IN(2,4,6);

> SS:=dsolve({ecd2,ci_2}, x(t), type=numeric,value=array(IN(2,4,6)));

Ejercicio

Usar los resultados numéricos de la derivada de x(t) para trazar la gráfica de vs t

> restart;

Sistemas.

Maple V tambien puede manejar sistemas de ecuaciones diferenciales.

Soluciones analiticas

> e1:=diff(x(t),t)=t+y(t); e2:=diff(y(t),t)=t-x(t);

Solución general

> dsolve({e1,e2},{x(t),y(t)});

Condiciones iniciales

> ci:=x(0)=1, y(0)=0;

> dsolve({e1,e2,ci}, {x(t),y(t)});

En particular, toda ecuación diferencial de segundo orden es equivalente a dos ecuaciones diferenciales de primer orden acopladas. Por ejemplo, la ecuacion que estudiamos anteriormente:

> ecd:=diff(x(t),t$2)+2*diff(x(t),t)+x(t)=1;

es equivalente a

> ec1:=diff(v(t),t)+2*v(t)+x(t)=1; ec2:=diff(x(t),t)=v(t);

> SS:=dsolve({ec1,ec2},{x(t),v(t)});

Condiciones iniciales

> ci:=x(0)=5, v(0)=0;

> SS:=dsolve({ec1,ec2,ci},{x(t),v(t)});

Ejercicios

• Comparar la solución de la ecuación de segundo orden con el de las dos ecuaciones de primer orden.
• Graficar las curvas de , asignando colores diferentes a cada curva

Soluciones numéricas

> restart;

Veamos la solución numérica de la ecuación de movimiento de un péndulo simple:

*

para valores numéricos de . Esta ecuación diferencial tiene solución analítica, en términos de integrales elípticas. Sin embargo, la estudiaremos numericamente como un sistema de dos ecuaciones acopladas de primer orden. Consideremos , mts

Las ecuaciones son:

> ec1:=diff(v(t),t)+(9.8/5)*sin(theta(t));
ec2:=v(t)=diff(theta(t),t);

Condiciones iniciales

> ci:=theta(0)=Pi/6,v(0)=0;

Solucion numérica

> S:=dsolve({ec1,ec2, ci}, {theta(t),v(t)}, type=numeric);

Valores particulares

> S(1); S(1.5); S(8.9);

Despliegue de 10 valores en el rango

> IN:=(t1,tn,n)->[seq( evalf(t1+i*(tn-t1)/(n-1)),i=0..n-1)];

> IN(0,4*Pi,10);

> SS:=dsolve({ec1,ec2, ci}, {theta(t),v(t)}, type=numeric, value=array(IN(0,4*Pi,10)));

Gráficas con odeplot

> plots[odeplot](S,[t,theta(t)], 0..4*Pi, numpoints=300);

Comparar las gráficas de odeplot para S y SS

> p1:=plots[odeplot](S,[t,theta(t)],0..4*Pi,color=black):
p2:=plots[odeplot](SS,[t,theta(t)],0..4*Pi, color=red): plots[display]({p1,p2});

Para entender bien que sucede, veamos los puntos graficados. En la grafica de SS, solo se grafican los puntos escogidos en el arreglo.

> p1:=plots[odeplot](S,[t,theta(t)],0..4*Pi,color=black, style=point,symbol=cross):
p2:=plots[odeplot](SS,[t,theta(t)],0..4*Pi, color=red, style=point, symbol=box): plots[display]({p1,p2});

Para graficas de sistemas, odeplot permite trazar varias graficas interesantes

Gráfica de

> plots[odeplot](S, [t,v(t)], 0..4*Pi);

Gráfica de (espacio de fase)

> plots[odeplot](S, [theta(t),v(t)], 0..4*Pi);

Gráfica 3dim

> plots[odeplot](S, [t,theta(t),v(t)], 0..4*Pi, axes=boxed,labels=[t,"theta(t)","v(t)"]);

>